/*
 *
  ***** BEGIN LICENSE BLOCK *****
 
  Copyright (C) 2009-2017 Olof Hagsand and Benny Holmgren

  This file is part of CLIXON.

  Licensed under the Apache License, Version 2.0 (the "License");
  you may not use this file except in compliance with the License.
  You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

  Unless required by applicable law or agreed to in writing, software
  distributed under the License is distributed on an "AS IS" BASIS,
  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  See the License for the specific language governing permissions and
  limitations under the License.

  Alternatively, the contents of this file may be used under the terms of
  the GNU General Public License Version 3 or later (the "GPL"),
  in which case the provisions of the GPL are applicable instead
  of those above. If you wish to allow use of your version of this file only
  under the terms of the GPL, and not to allow others to
  use your version of this file under the terms of Apache License version 2, 
  indicate your decision by deleting the provisions above and replace them with
  the  notice and other provisions required by the GPL. If you do not delete
  the provisions above, a recipient may use your version of this file under
  the terms of any one of the Apache License version 2 or the GPL.

  ***** END LICENSE BLOCK *****

 * XML parser
 */

%{

#include "clixon_config.h"

#include <stdio.h>
#include <string.h>
#include <stdint.h>

#include "clixon_xml_parse.tab.h"   /* generated file */

/* cligen */
#include <cligen/cligen.h>

/* clicon */
#include "clixon_queue.h"
#include "clixon_hash.h"
#include "clixon_handle.h"
#include "clixon_yang.h"
#include "clixon_xml.h"
#include "clixon_xml_parse.h"

/* Redefine main lex function so that you can send arguments to it: _ya is added to arg list */
#define YY_DECL int clixon_xml_parselex(void *_ya)

/* Dont use input function (use user-buffer) */
#define YY_NO_INPUT

/* typecast macro */
#define _YA ((struct xml_parse_yacc_arg *)_ya) 

#undef clixon_xml_parsewrap
int clixon_xml_parsewrap(void)
{
  return 1;
}

%}

%x START
%s STATEA
%s CMNT
%s STR
%s TEXTDECL
%s STRDQ
%s STRSQ

%%
<START>[0-9A-Za-z_\-]+ { clixon_xml_parselval.string = strdup(yytext);
                            return NAME; /* rather be catch-all */
                          }
<START>[ \t]+          ;
<START>\:              return *clixon_xml_parsetext;
<START>\n              { _YA->ya_linenum++;}
<START>"<?xml"         { BEGIN(TEXTDECL); return BTEXT;}
<START>"/>"            { BEGIN(STATEA); return ESLASH; }
<START>"<!--"          { BEGIN(CMNT); return BCOMMENT; }
<START>"</"            return BSLASH;
<START>[/=]            return *clixon_xml_parsetext; 
<START>\<              return *clixon_xml_parsetext;
<START>\>              { BEGIN(STATEA); return *clixon_xml_parsetext; }

<START>\"              { BEGIN(STR); return *clixon_xml_parsetext; }
<START>.               { clixon_xml_parselval.string = yytext; return CHAR; /*XXX:optimize*/ }


<STATEA>"</"               { BEGIN(START); return BSLASH; }
<STATEA>"<!--"             { BEGIN(CMNT); return BCOMMENT; }
<STATEA>\<                 { BEGIN(START); return *clixon_xml_parsetext; }
<STATEA>\n                 { clixon_xml_parselval.string = yytext;_YA->ya_linenum++; return (CHAR);}
<STATEA>.                  { clixon_xml_parselval.string = yytext; return CHAR; /*XXX:optimize*/}

<CMNT>"-->"           { BEGIN(START); return ECOMMENT; }
<CMNT>\n              _YA->ya_linenum++;
<CMNT>.               
<TEXTDECL>encoding       return ENC;
<TEXTDECL>version        return VER; 
<TEXTDECL>"="            return *clixon_xml_parsetext;
<TEXTDECL>"?>"           { BEGIN(START);return ETEXT;}
<TEXTDECL>\"             { BEGIN(STRDQ); return *clixon_xml_parsetext; }
<TEXTDECL>\'             { BEGIN(STRSQ); return *clixon_xml_parsetext; }

<STR>[^\"]+           { clixon_xml_parselval.string = strdup(yytext); return CHAR; }
<STR>\"               { BEGIN(START); return *clixon_xml_parsetext; }

<STRDQ>1\.[0-9]+       { clixon_xml_parselval.string = strdup(yytext);  return CHAR; }
<STRDQ>[^\"]+          { clixon_xml_parselval.string = strdup(yytext);  return CHAR; }
<STRDQ>\"              { BEGIN(TEXTDECL); return *clixon_xml_parsetext; }

<STRSQ>1\.[0-9]+       { clixon_xml_parselval.string = strdup(yytext);   return CHAR; }
<STRSQ>[^\']+          { clixon_xml_parselval.string = strdup(yytext);   return CHAR; }
<STRSQ>\'              { BEGIN(TEXTDECL); return *clixon_xml_parsetext; }

%%

/*! Initialize XML scanner.
 */
int
clixon_xml_parsel_init(struct xml_parse_yacc_arg *ya)
{
  BEGIN(START);
  ya->ya_lexbuf = yy_scan_string (ya->ya_parse_string);
  if (0)
    yyunput(0, "");  /* XXX: just to use unput to avoid warning  */
  return 0;
}

/*! Exit xml scanner */
int
clixon_xml_parsel_exit(struct xml_parse_yacc_arg *ya)
{
   yy_delete_buffer(ya->ya_lexbuf);
   clixon_xml_parselex_destroy();  /* modern */

  return 0;
}